Eclairage lever/coucher de soleil

Bonjour à tous,
N'ayant pas assez de lumière dans mon bac j'ai décidé de modifier la galerie.
Je suis passé de 1x25w à 2x39w.
Pour piloter tout ça je suis passé par un arduino et un ballast dimmable.
Ce montage permet d'allumer et éteindre graduellement.
Tous les paramètres sont modifiables via une application bluetooth que j'ai développée sur Android.
Quelques photos:
     

Budget :
Arduino Nano 5€
Module RTC DS3231 2.5€
Module Bluetooth HC-06 4.5€
Relai 5V 1.5€ (modèle avec bornier de chaque côté)
Abaisseur de tension LM2596 1.5€
Alimentation 12VDC 7€. J'en avait déjà une qui coûte plus cher parce qu'elle est capable de délivrer plus de courant mais c'est du luxe pour rien...
Total = 22€
Réalisation du circuit imprimé et composants, prix dérisoire donc grand total 30€ (les 22€ précédents compris)

Je ne compte pas la partie électricité (tubes, ballast, réflecteur)

D'abord une photo d'ensemble avec l'identification des différentes pièces:


Donc le contrôleur c'est un arduino nano.
J'ai choisi un nano parce que c'est le plus petit modèle avec un port USB. Je l'ai acheté seul, pas de kit ni rien donc pas cher.
Il faut un câble mini USB pour le programmer (comme le câble de beaucoup d'appareils photo).
Dans un arduino il n'y a pas d'horloge donc pour cette application j'ai ajouté un module RTC (Real Time Clock).
Le relais sert à alimenter ou non le ballast via une sortie de l'arduino.
Avec arduino + RTC + Relais on a donc un fonctionnement équivalent aux programmateurs sur prise traditionnels.
J'ai utilisé une deuxième sortie de l'arduino pour faire varier l'intensité lumineuse.
L'arduino est capable de faire varier une tension entre 0 et 5V mais c'est une sortie PWM, c'est à dire qu'il envoie des impulsions de 5V. Plus les impulsions sont longues et rapprochées plus la tension est proche de 5V et plus elles sont courtes et éloignées plus on est proche de 0V.
Le but du circuit électronique est de convertir ce signal PWM 0-5V en signal continu de 0 à 10V.
Il y a donc sur ce circuit un ampli op (la bête à 8 pattes) et des résistances et condensateurs pour lisser le signal. Le potentiomètre permet d'affiner la tension maxi de sortie à 10V.
Ce circuit est alimenté en 12V, ce qui fait un peu trop pour l'arduino (normalement c'est compatible mais je ne voulais pas qu'il chauffe). J'ai donc ajouté un convertisseur de tension qui me permet d'alimenter l'arduino en 6V.
Le dernier module est le bluetooth qui permet de communiquer avec l'arduino via un téléphone portable, et avec l'appli android développée.

Sur l'application android on paramètre l'heure d'allumage, l'heure d'extinction, le temps d'allumage, le temps d'extinction, la puissance mini et maxi.
Si par exemple on programme:
Allumage 10H00 rampe 60min
Extinction 22H00 rampe 30min
Mini 5%
Maxi 90%

La lumière va être allumée de 10h à 22h
Elle va s'allumer progressivement de 5% à 90% de 10h à 11h
Elle va s'éteindre progressivement de 90% à 5% de 21h30 à 22h

Voila j'ai retrouvé l'adresse du site qui m'a permis de démarrer:
http://www.wikidebrouillard.org/index.php/Android_et_arduino
et celui-là qui utilise AppInventor2 (actuel):
http://mathsp.tuxfamily.org/spip.php?article278

Si des personnes sont intéressées et veulent plus de détails, pas de problème.
J3J3

Intéressant!!!!

A combien cela revient il?

Pas trop compliquer à programmer?

c'est cool ça j'aimerai faire pareil ou as tu trouvé tes composants ?
tu en as eu pour combien ?
et on peux faire pareil que toi ?

je suis avec grande curiosité

hugo

Pour la partie éclairage, c'est des tubes T5 et un ballast dimmable donc la différence de prix se fait sur le ballast, j'ai eu le miens sur eBay pour 35€. C'est vraiment pas cher.
Pour toute la partie électronique faut compter entre 20 et 30€.
La différence de prix entre 2x39w tout ou rien et 2x39w dimmable n'est pas énorme.
Je peux fournir toutes les infos à ceux qui souhaitent, pas de soucis.

cool ;)oui je veux bien tient je te file mon mail: gueanthugo@gmail.com

Je vais donner les détails ce soir, pour l'instant je n'ai pas le temps.
Je vais mettre les infos sur le forum plutôt que sur ton mail, ça pourra servir aux autres.
J3J3

merci oui autant faire profiter à tout le monde

Voici donc plus d'infos :

Tubes T5 39w trouvables dans toutes les boutiques aquario.

Pour le reste des pièces c'est soit eBay soit DX
Ballast T5 2x39W dimmable 1-10V 30€
Arduino Nano 5€
Module RTC DS3231 2.5€
Module Bluetooth HC-06 4.5€
Relai 5V 1.5€ (modèle avec bornier de chaque côté)
Abaisseur de tension LM2596 1.5€
Alimentation 12VDC 7€. J'en avait déjà une qui coûte plus cher parce qu'elle est capable de délivrer plus de courant mais c'est du luxe pour rien...
Total = 22€

Réalisation du circuit imprimé et composants, prix dérisoire donc grand total 30€ (les 22€ précédents compris)
Pour le circuit imprimé il faut 3 résistances, 2 potentiomètres, 2 condensateurs et des borniers si on le souhaite mais on peut aussi souder les fils...
Sur mon circuit, tous les accessoires sont débrochables.(module RTC, BT, régulateur de tension, Arduino)
J'ai fait un circuit imprimé parce que j'avais tout ce qu'il faut pour le graver mais on peut aussi faire le montage sur une platine d'essai.
Mon premier montage est fait sur une platine d'essai et était moins complet, il ne convertissait que la sortie PWM de l'Arduino en 0-10V, mais ça marche aussi!

Pour la partie programmation, je n'ai pas trouvé ça compliqué mais après ça dépend des compétences de chacun.
Le programme de l'Arduino est développé avec le logiciel Arduino et l'application Android est développée avec AppInventor.
Pour AppInventor, j'ai trouvé ça un peu galère parce qu'au bout d'un moment ça rame et je suis pas fan de la programmation par blocs, je préfère les lignes de code...
Du coup il y a des choses qu'il faudrait améliorer mais je ne sais pas trop comment et puis je n'ai pas fait l'application pour la vendre alors elle me va bien comme ça!

J3J3

Edit: J'ai oublié : un réflecteur, les douilles et du scotch alu pour le deuxième réflecteur. Un ampli op LM358

En résumé
partie électrique : tubes, douilles, ballast, réflecteur... 100€
partie électronique : Arduino et ses modules, circuit imprimé, composants... 30€

J'ai un peu plus de temps donc je vais essayer de détailler.
D'abord une photo d'ensemble avec l'identification des différentes pièces:


Donc le contrôleur c'est un arduino nano, il y a effectivement plusieurs modèles et plusieurs kits.
J'ai choisi un nano parce que c'est le plus petit modèle avec un port USB. Je l'ai acheté seul, pas de kit ni rien donc pas cher.
Il faut un câble mini USB pour le programmer (comme le câble de beaucoup d'appareils photo).
Dans un arduino il n'y a pas d'horloge donc pour cette application j'ai ajouté un module RTC (Real Time Clock).
Le relai sert à alimenter ou non le ballast via une sortie de l'arduino.
Avec arduino + RTC + Relai on a donc un fonctionnement équivalent aux programmateurs sur prise traditionnels.
J'ai utilisé une deuxième sortie de l'arduino pour faire varier l'intensité lumineuse.
L'arduino est capable de faire varier une tension entre 0 et 5V mais c'est une sortie PWM, c'est à dire qu'il envoie des impulsions de 5V. Plus les impulsions sont longues et rapprochées plus la tension est proche de 5V et plus elles sont courtes et éloignées plus on est proche de 0V.
Le but du circuit électronique est de convertir ce signal PWM 0-5V en signal continu de 0 à 10V.
Il y a donc sur ce circuit un ampli op (la bête à 8 pattes) et des résistances et condensateurs pour lisser le signal. Le potentiomètre permet d'affiner la tension maxi de sortie à 10V.
Ce circuit est alimenté en 12V, ce qui fait un peu trop pour l'arduino (normalement c'est compatible mais je ne voulais pas qu'il chauffe). J'ai donc ajouté un convertisseur de tension qui me permet d'alimenter l'arduino en 6V.
Le dernier module est le bluetooth qui permet de communiquer avec l'arduino via un téléphone portable, et avec l'appli android développée.

Sur l'application android on paramètre l'heure d'allumage, l'heure d'extinction, le temps d'allumage, le temps d'extinction, la puissance mini et maxi.
Si par exemple on programme:
Allumage 10H00 rampe 60min
Extinction 22H00 rampe 30min
Mini 5%
Maxi 90%

La lumière va être allumée de 10h à 22h
Elle va s'allumer progressivement de 5% à 90% de 10h à 11h
Elle va s'éteindre progressivement de 90% à 5% de 21h30 à 22h

Voici le programme de l'arduino....attention ça peut être indigeste pour certains  
Bonne lecture et j'espère que c'est plus compréhensible maintenant  
S'il y a des questions (je serais surpris du contraire), j'essaierai d'y répondre le mieux possible
J3J3

Code:

#include <Wire.h>
#include <SPI.h>  // not used here, but needed to prevent a RTClib compile error
#include "RTClib.h"
#include <EEPROM.h>

RTC_DS3231 rtc;
    
const int PinRelay = 10;     // Sortie relai
const int PinVariat = 5;    // Sortie PWM
int DTy;                    // Année
int DTM;                    // Mois
int DTd;                    // Jour
int DTh;                    // Heure
int DTm;                    // Minute
int DTs;                    // Seconde
int HDeb;                   // Heure d'allumage
int MinDeb;                 // Minute d'allumage
int HFin;                   // Heure d'extinction
int MinFin;                 // Minute d'extinction
int TpFadeOn;               // Durée rampe d'allumage (min)
int TpFadeOff;              // Durée rampe extinction (min)
int HFadeOn;                // Heure de fin de rampe allumage
int MinFadeOn;              // Minute de fin de rampe allumage
int HFadeOff;               // Heure de début extinction
int MinFadeOff;             // Minute de début extinction
float ValMin;               // % minimum de la sortie en auto
float ValMax;               // % maximum de la sortie en auto
float Inc;                  // Incrément (%/s)
float Dec;                  // Décrément (%/s)
float ValVar = 0.0;         // % de la sortie
float ValVarAuto = 0.0;     // % de la sortie en auto
float ValVarManu = 0.0;     // % de la sortie en manu
int FadeValue = 0;          // Valeur à affecter à la sortie PWM
bool OutRelay = LOW;        // Bit d'équation de la sortie relai
bool FadeOn = LOW;          // En cours d'allumage
bool FadeOff = LOW;         // En cours d'extinction
bool AutoOn = LOW;          // Relai à 1 en auto
bool ForcOn = LOW;          // Forçage de la sortie relai à 1
bool ForcOff = LOW;         // Forçage de la sortie relai à 0
int sMem;                   // Mémoire du nombre de secondes
char ReceivedChar;          // Premier caractère reçu
String ReceivedText = "";   // Chaine reçue d'Android Txt1:Val1*Txt2:Val2....
String ExtractedText = "";  // Chaine extraite jusqu'au délimiteur * Txt1:Val1
String VarToChange = "";    // Nom de la variable concernée Txt1
int ValToChange = 0;        // Valeur de la variable concernée Val1

void setup (){
  //Lecture des données
  HDeb=EEPROM.read(0);
  MinDeb=EEPROM.read(1);
  HFin=EEPROM.read(2);
  MinFin=EEPROM.read(3);
  TpFadeOn=EEPROM.read(4);
  TpFadeOff=EEPROM.read(5);
  ValMin=EEPROM.read(6);
  ValMax=EEPROM.read(7);
  
  // initialisation de la sortie relai
  pinMode(PinRelay, OUTPUT);
  
  Serial.begin(9600);
#ifdef AVR
  Wire.begin();
#else
  Wire1.begin();
#endif
  rtc.begin();

 if (! rtc.isrunning()) {
    // following line sets the RTC to the date & time this sketch was compiled
    rtc.adjust(DateTime(__DATE__, __TIME__));
  }
}

void loop () {
  
    // Lecture de l'heure
    DateTime now = rtc.now();
    int yActu = now.year();
    int MActu = now.month();
    int dActu = now.day();
    int hActu = now.hour();
    int mActu = now.minute();
    int sActu = now.second();
  
    // Lecture de la température de la carte RTC
    float temperature = rtc.getTemperature();
    
    // Création du bit seconde
    bool frtSec = sActu!=sMem;
    sMem=sActu;
 
if( Serial.available() )  // Données à lire
  {
    ReceivedText = "";     // Chaine reçue d'Android
    ExtractedText = "";    // Chaine extraite jusqu'au délimiteur *
    
    while (Serial.available())
   {
      // Création de la chaine de caractères
      ReceivedChar = Serial.read();
      ReceivedText += ReceivedChar;
    }
  }
  while (ReceivedText.length() > 0)
  {
    if (ReceivedText.indexOf('*') > 0)
      {
        // Si la chaine contient le caractère *
        // Résultat : Txt1:Val1
        ExtractedText = ReceivedText.substring(0, ReceivedText.indexOf('*'));
        // Résultat : Txt2:Val2....
        ReceivedText = ReceivedText.substring(ReceivedText.indexOf('*')+1);
        // Résultat : Txt1
        VarToChange = ExtractedText.substring(0, ExtractedText.indexOf(':'));
        // Résultat : Val1
        ValToChange = ExtractedText.substring(ExtractedText.indexOf(':')+1).toInt();
      }
    else
      {
        ReceivedText = "";
      }
    
    // Traitement des données reçues
    // Changement de mode : Auto, Manu On, Manu Off
    if( VarToChange == "Mode" )
    {
      ForcOn = ValToChange == 1;
      ForcOff = ValToChange == 0;
      if (ForcOn)                    {ValVarManu = ValVar;}
      if (ForcOff)                   {ValVarManu = 0;}
      if (!ForcOn & !ForcOff)        {ValVarAuto = ValVar;}
    }
    if( VarToChange == "HD" )        {HDeb = ValToChange;EEPROM.write(0, HDeb);}
    if( VarToChange == "MD" )        {MinDeb = ValToChange;EEPROM.write(1, MinDeb);}
    if( VarToChange == "TpOn" )      {TpFadeOn = ValToChange;EEPROM.write(4, TpFadeOn);}
    if( VarToChange == "HF" )        {HFin = ValToChange;EEPROM.write(2, HFin);}
    if( VarToChange == "MF" )        {MinFin = ValToChange;EEPROM.write(3, MinFin);}
    if( VarToChange == "TpOff" )     {TpFadeOff = ValToChange;EEPROM.write(5, TpFadeOff);}
    if( VarToChange == "VMin" )    {ValMin = ValToChange;EEPROM.write(6, ValMin);}
    if( VarToChange == "VMax" )    {ValMax = ValToChange;EEPROM.write(7, ValMax);}
    if( VarToChange == "ValManu" )   {ValVarManu = ValToChange;}
    if( VarToChange == "DTy" )       {DTy = ValToChange;}
    if( VarToChange == "DTM" )       {DTM = ValToChange;}
    if( VarToChange == "DTd" )       {DTd = ValToChange;}
    if( VarToChange == "DTh" )       {DTh = ValToChange;}
    if( VarToChange == "DTm" )       {DTm = ValToChange;}
    if( VarToChange == "DTs" )       {DTs = ValToChange;}
    if( VarToChange == "SetDT" )     {rtc.adjust (DateTime(DTy,DTM,DTd,DTh,DTm,DTs));}
  }
  
   // Sortie relai
    if (hActu>HDeb | hActu==HDeb & mActu>=MinDeb){AutoOn = HIGH;}
    if (hActu>HFin | hActu==HFin & mActu>=MinFin){AutoOn = LOW;}
    if (AutoOn & !ForcOff | ForcOn)  {OutRelay = HIGH;}
    if (!AutoOn & !ForcOn | ForcOff) {OutRelay = LOW;}
    digitalWrite(PinRelay, OutRelay);
    
    int m;
    int h;
    // En cours d'allumage
    h = TpFadeOn/60;
    m = TpFadeOn - h*60;
    HFadeOn = HDeb + h;
    MinFadeOn = MinDeb + m;
    if (MinFadeOn>59){MinFadeOn=MinFadeOn-60;HFadeOn++;}
    if (HFadeOn>23){HFadeOn=HFadeOn-24;}
    FadeOn = hActu>HFadeOn | hActu==HFadeOn & mActu>=MinFadeOn;
    Inc = (ValMax-ValMin)/(60.0*TpFadeOn);
    
    // En cours d'extinction
    h = TpFadeOff/60;
    m = TpFadeOff - h*60;
    HFadeOff = HFin - h;
    MinFadeOff = MinFin - m;
    if (MinFadeOff<0){MinFadeOff=60+MinFadeOff;HFadeOff--;}
    if (HFadeOff<0){HFadeOff=24+HFadeOff;}
    FadeOff = hActu>HFadeOff | hActu==HFadeOff & mActu>=MinFadeOff;
    Dec = (ValMax-ValMin)/(60.0*TpFadeOff);
    
    // Tempo entre chaque incrément/décrément
    if (frtSec)
    {//DEBUG
  
    // Augmentation de la sortie
     if (AutoOn & !ForcOn & !FadeOff & ValVarAuto < ValMax){ValVarAuto = ValVarAuto + Inc;}
      
    // Baisse de la sortie une heure avant extinction
     if (FadeOff & !ForcOn & ValVarAuto > ValMin){ValVarAuto = ValVarAuto - Dec;}
      
   }
    
    // Limites de la sortie auto
    if (ValVarAuto < ValMin){ValVarAuto = ValMin;}
    if (ValVarAuto > ValMax){ValVarAuto = ValMax;}
    
    // Recopie de la sortie
    if (ForcOn | ForcOff)
    {
      ValVar = ValVarManu;
    }
    else
    {
      ValVar = ValVarAuto;
    }
    
    // Limites de la sortie
    if (ValVar < 0 | !OutRelay){ValVar = 0;}
    if (ValVar > 100){ValVar = 100;}
    
    // Ecriture de la sortie PWM
    FadeValue = 25+230*ValVar/100; // Décalage 0-100% en 0.5-5V pour passer à 1-10V avec ampli-op
    analogWrite(PinVariat, FadeValue);
    
    // Envoi des infos à Android
    if (frtSec)
    {
      // Etats
      int STRelay;
      int Mode;
      if (OutRelay){STRelay = 1;}else{STRelay = 0;}
      if (ForcOff){Mode = 0;}
      if (ForcOn){Mode = 1;}
      if (!ForcOff & !ForcOn){Mode = 2;}
 
     Serial.print("DTy");
      Serial.print(yActu);
      Serial.print("*DTM");
      Serial.print(MActu);
      Serial.print("*DTd");
      Serial.print(dActu);
      Serial.print("*DTh");
      Serial.print(hActu);
      Serial.print("*DTm");
      Serial.print(mActu);
      Serial.print("*DTs");
      Serial.print(sActu);
      Serial.print("*ValVar");
      Serial.print(ValVar);
      Serial.print("*Relay");
      Serial.print(STRelay);
      Serial.print("*Mode");
      Serial.print(Mode);
      Serial.print("*");
  
     // Paramètres
      Serial.print("HDeb");
      Serial.print(HDeb);
      Serial.print("*MinDeb");
      Serial.print(MinDeb);
      Serial.print("*TpOn");
      Serial.print(TpFadeOn);
      Serial.print("*HFin");
      Serial.print(HFin);
      Serial.print("*MinFin");
      Serial.print(MinFin);
      Serial.print("*TpOff");
      Serial.print(TpFadeOff);
      Serial.print("*ValMin");
      Serial.print(ValMin);
      Serial.print("*ValMax");
      Serial.print(ValMax);
      Serial.print("*");
    }  
   delay(300);
}

banzai!

Faut être ingénieur pour piger

Mais non... je suis pas ingé  :##06: 

Ca me disais vachement de le faire, mais la je crois que je vais laisser tomber et repasser au on/off sur programmateur ^^' plus simple à comprendre.
En tout cas, super idée !!!!

arry a écrit:Ca me disais vachement de le faire, mais la je crois que je vais laisser tomber et repasser au on/off sur programmateur ^^' plus simple à comprendre.
En tout cas, super idée !!!!

Si tu es intéressé et que c'est la programmation qui te rebutes, je peux te filer un coup de main... Tu peux aussi reprendre mon programme et l'appli Android sans rien comprendre et ça va marcher.
Le On/Off c'est bien mais on fait pas tout ce qu'on veut. Je voulais aussi faire avec un variateur parce que je suis passé de 25 à 78w et ça me permet de le faire en douceur en espérant éviter une explosion d'algues. En ce moment je suis à 60% max.

beau travail

Explosion d'algue du à la trop forte intensité?

Je regardais justement pour acheter un visilux 2X40W car je n'ai que un visilux 1X30 W pour mon 160L ....

En réalité un peu tout me rebute ^^ c'est pire que du chinois ^^ je ne connais rien en programmation, ni en électricité. Je ne sais pas souder et n'ai rien pour le faire, ...
Sinon ce serait magnifique !!

Ah oui...là pour le coup c'est un sacré challenge ! Tu peux toujours t'orienter vers une babyfish mais c'est pas le même prix...

C'est gentil mais non, je n'ai pas beaucoup de moyens financiers ^^'

Bonne continuation !

Bonjour trouvant votre post intéressant mais trop compliqué a faire pour mes 10 doigts :##18: . je me suis dirigé ver une ballast  2 x 80 watt dimmable et le fameux babyfish (prix pas trop excessif ). Mais un petit probleme ce pose a moi  :##12: :##12: :##12: :##12: 
Quelqu'un aurait'il un plan pour assemblé tout se fourbi  :##10: ?????
Merci d'avance de votre aide a tous  :##06:

Pour le ballast normalement le câblage des tubes est indiqué dessus et sinon tu dois avoir la doc avec le babyfish non ?
C'est quel modèle le ballast ?

J3J3 a écrit:Pour le ballast normalement le câblage des tubes est indiqué dessus et sinon tu dois avoir la doc avec le babyfish non ?
C'est quel modèle le ballast ?

Salut je n'ai encore rien acheté je voulais justement voir un shéma d'assemblage du toute pour me faire une idée de comment faire ma gallerie. mais pour info voici le lien ou je vais surement acheter mon ballast: http://www.aqualight-solution.com/ballasts-t5-dimmable/1222-ballast-t5-2x80-watts.html
Et je n'ai pas acheté le babyfish donc pas de notice...... :##22: 

La notice de chez Babyfish:
http://www.babyfish.fr/doc/fr/dimled/dimled.shtml
Pour le ballast faut juste savoir le type d'entrée pour savoir si c'est compatible. Demande à Aqualight.(1-10v Pwm....)

je dois demander quoi a aqualight ??? :##10: :##10: :##10: 

super boulot mais mon neurone a cramé en route mdrr, heureusement que le prix des rampes et contrôleur on bien baissé, j'aurais aimé payé moins quand jle ferrais mais là ça me dépasse lool

panpanovsky a écrit:je dois demander quoi a aqualight ??? :##10: :##10: :##10: 

Tu leur demandes comment on pilote le dimmer. Pwm ou 1- 10v

bonjour,
je suis avec grand interet ton sujet....
j ai moi meme deja realisé une rampe led a base de led cree, controlé par un arduino et un ecran tactile (grace au site ilot recif et son sebduino) le tout pour un auarium d 'eau douce...si vous voulez plus d info je peux detailler..

ce qui m'interresse énormément dans ton projet, c'est partie controle avec la partie android....j'ecume les forums depuis longtemps et c'est la 1ere fois que je vois une solution concrete...
pourrait on en savoir plus ,a partir de quel programme tu codes (et pkoi pas ton code... :##06: )

le gros point noir pour moi de gerer l arduino avec un ecran tactile est le nombre de sortie pwm utilisé...
merci